n = REQUEST (question_name, name_or_index, variable1 [, variable2, ...]) n = REQUEST{2} (question_name, name_or_index, name, variable1 [, variable2, ...]) n = REQUEST{3} (question_name, name, name_or_index_array, variable1 [, variable2, ...]) n = REQUEST{4} (question_name, name_or_index, index, name, variable1 [, variable2, ...])

The first parameter represents the question string while the second (or more) represents the object of the question (if it exists). The other parameters are variable names in which the return values (the answers) are stored.
The function’s return value is the number of the answer (in the case of a badly formulated question or a nonexistent name, the value will be 0).

ARCHICAD identifies the order and number of the input parameters by either the version of the REQUEST command, or the exact name (as string constant) of the request option. This means that using the first or both of the following options is the safest:

• name of the request is always a constant string
• version is added to the command

Returns information in the given variable(s)

Request Parameter Script Compatibility

The use of most requests in parameter scripts (or master scripts run as parameter script) can result in unstable returned values, therefore should be avoided.

Compatibility up to ARCHICAD 19: The use of most requests in parameter scripts (or master scripts run as parameter script) could result in unreliable returned values.
Compatibility starting from ARCHICAD 20: the following applies in parameter script cases:

• the request expression will always have 0 as success return value
• the requested values will contain a type-matching default only (empty string or 0)

Using these restricted requests in the parameter script will also generate GDL warnings starting from ARCHICAD 19.

To check the parameter script compatibility, refer to the table below:

Legend:
works without restriction
works (with additional warning)
does not work: expression returns 0, while containing dummy type-matching defaults in returned variables (empty string or 0) – with additional warning

Compatibility in Parameter Script	ARCHICAD 18	ARCHICAD 19	ARCHICAD 20 and later
A
ANCESTRY_INFO
ANGULAR_DIMENSION
ANGULAR_LENGTH_DIMENSION
AREA_DIMENSION
ASSOCEL_PROPERTIES
ASSOCLP_NAME
ASSOCLP_PARVALUE
ASSOCLP_PARVALUE_WITH_DESCRIPTION
AUTOTEXT_LIST	–	–
B
BUILDING_MATERIAL_INFO
C
CALC_ANGLE_UNIT
CALC_AREA_UNIT
CALC_LENGTH_UNIT
CALC_VOLUME_UNIT
CLASS_OF_FILL
CLEAN_INTERSECTIONS
COMPONENT_PROJECTED_AREA
COMPONENT_PROPERTY_TREE_OF_PARENT	–	–
COMPONENT_PROPERTY_VALUES_OF_PARENT	–	–
COMPONENT_VOLUME
CONFIGURATION_NUMBER	–	–
CONSTR_FILLS_DISPLAY
CUSTOM_AUTO_LABEL
D
DATETIME
DOOR_SHOW_DIM
E
ELEVATION_DIMENSION
F
FLOOR_PLAN_OPTION
FONTNAMES_LIST
FULL_ID_OF_PARENT	–
G
GSID_INFO	–	–
H
HEIGHT_OF_STYLE
HOME_STORY
HOME_STORY_OF_OPENING
HOMEDB_INFO
I
ID_OF_MAIN
LAYOUT_LENGTH_UNIT
LAYOUT_TEXT_SIZE_UNIT
LEVEL_DIMENSION
LINEAR_DIMENSION
M
MATCHING_PROPERTIES
MATERIAL_INFO
MEP_ROUTE_ATTRIBUTES	–	–
MODEL_LENGTH_UNIT
MODEL_TEXT_SIZE_UNIT
N
NAME_OF_FILL
NAME_OF_LINE_TYPE
NAME_OF_LISTED
NAME_OF_MACRO
NAME_OF_MAIN
NAME_OF_MATERIAL
NAME_OF_PLAN
NAME_OF_PROGRAM
NAME_OF_STYLE
P
PEN_OF_RGB
PROGRAM_INFO
PROPERTIES_OF_PARENT	–	–
PROPERTY_NAME	–	–
PROPERTY_TREE_OF_PARENT	–	–
PROPERTY_VALUE_OF_PARENT	–	–
PROPERTY_VALUES_OF_PARENT	–	–
R
RADIAL_DIMENSION
REFERENCE_LEVEL_DATA
RGB_OF_MATERIAL
RGB_OF_PEN
S
SILL_HEIGHT_DIMENSION
STORY
STORY_INFO
STYLE_INFO
SUM_WITH_ROUNDING	–	–
T
TEXTBLOCK_INFO
W
VIEW_ROTANGLE
WINDOW_DOOR_DIMENSION
WINDOW_DOOR_SHOW_DIM
WINDOW_DOOR_ZONE_RELEV
WINDOW_DOOR_ZONE_RELEV_OF_OWNER
WINDOW_SHOW_DIM
WORKING_ANGLE_UNIT
WORKING_LENGTH_UNIT
Z
ZONE_CATEGORY
ZONE_COLUS_AREA
ZONE_RELATIONS
ZONE_RELATIONS_OF_OWNER

Details of Requests

n = REQUEST ("Name_of_program", "", program_name)

Returns in the given variable the name of the program, e.g., “”.
Expression returns 0 and contains dummy return values (emtpy string or 0) if used in parameter script, causing additional warning.

n = REQUEST ("Name_of_program", "", program_name)
PRINT program_name

n = REQUEST ("Name_of_macro", "", my_name)

n = REQUEST ("Name_of_main", "", main_name)

After executing these function calls, the my_name variable will contain the name of the macro,
while main_name will contain the name of the main macro (if it doesn’t exist, empty string).

n = REQUEST ("ID_of_main", "", id_string)

For library parts placed on the floor plan,
returns the identifier set in the tool’s settings dialog box in the id_string variable (otherwise empty string).
Not working on annotation elements (e.g. Label, D/W Marker, Zone Stamp).
Expression returns 0 and contains dummy return values (emtpy string or 0) if used in parameter script, causing additional warning.

n = REQUEST ("Full_ID_of_parent, "", id_string)

For annotation elements linked or hotlinked on the floo r plan,
returns all identifiers (Master ID) of the linked modules and the parent library parts’
identifier set in the tool’s settings dialog box in the id_string variable (otherwise empty string).
Expression returns 0 and contains dummy return values (emtpy string or 0) if used in parameter script, causing additional warning.

n = REQUEST ("Name_of_plan", "", name)

Returns in the given variable the name of the current project.
Expression returns 0 and contains dummy return values (emtpy string or 0) if used in parameter script, causing additional warning.

n = REQUEST ("Story", "", index, story_name)

Returns in the index and story_name variables the index and the name of the current story. Should be used on floorpan only, as “current story” is not defined in other view types.
Expression returns 0 and contains dummy return values (emtpy string or 0) if used in parameter script, causing additional warning.

n = REQUEST ("Home_story", "", index, story_name)

Returns in the index and story_name variables the index and the name of the home story.

n = REQUEST ("Home_story_of_opening", "", index, story_name)

Returns the index and the name of the home story of the opening in the index and story_name variables.
The home story is the first story, where the opening is visible.
Can be used in scripts of doors, windows, wallends, corner windows and skylights, and in the script of their labels and markers.
Causes warning if used in parameter script.

n = REQUEST ("Story_info", expr, nStories, index1, name1, elev1, height1 [, index2, name2, ...])

Returns the story information in the given variables: number of stories and story index, name, elevation, height to next successively.
If expr is a numerical expression, it means a story index: only the number of stories and the information on the specified story is returned.
If expr is a string expression, it means that information on all stories is requested.
The return value of the function is the number of successfully retrieved values.

DIM t[]
n = REQUEST ("STORY_INFO", "", nr, t)
FOR i = 1 TO nr
    nr = STR ("%.0m", t [4 * (i - 1) + 1])
    name = t [4 * (i - 1) + 2]
    elevation = STR ("%m", t [4 * (i - 1) + 3])
    height = STR ("%m", t [4 * (i - 1) + 4])
    TEXT2 0, -i, nr + "," + name + "," + elevation + "," + height
NEXT i

With the following requests, you can learn the dimension formats set in the Options/Project Preferences/Dimensions and Calculation Units & Rules dialog boxes.
These requests return a format string that can be used as the first parameter in the STR () function.

n = REQUEST ("Linear_dimension", "", format_string)

n = REQUEST ("Angular_dimension", "", format_string)

Expression returns 0 and contains dummy return values (emtpy string or 0) if used in parameter script, causing additional warning.

n = REQUEST ("Angular_length_dimension", "", format_string)

Expression returns 0 and contains dummy return values (emtpy string or 0) if used in parameter script, causing additional warning.

n = REQUEST ("Radial_dimension", "", format_string)

Expression returns 0 and contains dummy return values (emtpy string or 0) if used in parameter script, causing additional warning.

n = REQUEST ("Level_dimension", "", format_string)
Expression returns 0 and contains dummy return values (emtpy string or 0) if used in parameter script, causing additional warning.

n = REQUEST ("Elevation_dimension, "", format_string)

Expression returns 0 and contains dummy return values (emtpy string or 0) if used in parameter script, causing additional warning.

n = REQUEST ("Window_door_dimension", "", format_string)

n = REQUEST ("Sill_height_dimension", "", format_string)

n = REQUEST ("Area_dimension", "", format_string)

n = REQUEST ("Calc_length_unit", "", format_string)

n = REQUEST ("Calc_area_unit", "", format_string)

Expression returns 0 and contains dummy return values (emtpy string or 0) if used in parameter script, causing additional warning.

n = REQUEST ("Calc_volume_unit", "", format_string)

n = REQUEST ("Calc_angle_unit", "", format_string)

Expression returns 0 and contains dummy return values (emtpy string or 0) if used in parameter script, causing additional warning.

format = ""
num = 60.55
n = REQUEST ("Angular_dimension", "",format) !"%.2dd"
TEXT2 0, 0, STR (format, num) !60.55

n = REQUEST ("Clean_intersections", "", state)

Returns the state of the Clean Wall & Beam Intersections feature (1 when turned on, 0 when off)
Expression returns 0 and contains dummy return values (emtpy string or 0) if used in parameter script, causing additional warning.

n = REQUEST ("Zone_category", "", name, code)

For zones, returns the name and the code string of the current zone category.

n = REQUEST ("Zone_relations", "", category_name, code, name, number [, category_name2, code2, name2, number2])

Returns in the given variables the zone category name and code and the name and number of the zone
where the library part containing this request is located. For doors and windows, there can be a maximum of two zones.
The return value of the request is the number of successfully retrieved values (0 if the library part is not inside any zone).

n = REQUEST ("Zone_relations_of_owner", "", category_name, code, name, number [, category_name2, code2, name2, number2])

Returns in the given variables the category name & code and the zone name & number of the zone
where the owner of the object is located. So, it is meaningful, if the library part has owner (door-window labels and door-window markers, etc.).
In case of a door label, its owner is the door. For doors and windows, there can be a maximum of two related zones.
The return value of the request is the number of successfully retrieved values
(0 if the object has no owner, or its owner is not inside any zone).
Causes warning if used in parameter script.

n = REQUEST ("Zone_colus_area", "", area)

Returns in the area variable the total area of the columns placed in the current zone. Effective only for Zone Stamps.
Available only for compatibility reasons. It is recommended to use quantities set in Zone Stamp fix parameters.
Expression returns 0 and contains dummy return values (emtpy string or 0) if used in parameter script, causing additional warning.

n = REQUEST ("Custom_auto_label", "", name)

Returns in the name variable the name of the custom auto label of the library part or an empty string if it does not exist.
Expression returns 0 and contains dummy return values (emtpy string or 0) if used in parameter script, causing additional warning.

n = REQUEST ("Rgb_of_material", name, r, g, b)

n = REQUEST ("Rgb_of_pen", penindex, r, g, b)

n = REQUEST ("Pen_of_RGB", "r g b", penindex)

Like the REQ() function (but in just one call),
returns in the specified variables the value of the r, g, b components of the material and pen,
or the index of the pen corresponding to the given RGB values.
All 3 expression return 0 and contains dummy return values (emtpy string or 0) if used in parameter script, causing additional warning.

n = REQUEST ("Height_of_style", name, height [, descent, leading])

Returns in the given variables the total height of the style measured in millimeters (height in meters is height / 1000 * GLOB_SCALE);
the descent (the distance in millimeters from the text base line to the descent line)
and the leading (the distance in millimeters from the descent line to the ascent line).

n = REQUEST ("Style_info", name, fontname [, size, anchor, face_or_slant])

Returns information in the given variables on the previously defined style
(see style parameters at the DEFINE STYLE command).
Can be useful in macros to collect information on the style defined in a main script.
Causes warning if used in parameter script.

n = REQUEST ("Name_of_material", index, name)

Returns in the variable the material name identified by index.
Expression returns 0 and contains dummy return values (emtpy string or 0) if used in parameter script, causing additional warning.

n = REQUEST ("Name_of_building_material", index, name)

Returns in the variable the building material name identified by index.
Expression returns 0 and contains dummy return values (emtpy string or 0) if used in parameter script, causing additional warning.

n = REQUEST ("Name_of_fill", index, name)

Returns in the name variable the fill name identified by index.
Expression returns 0 and contains dummy return values (emtpy string or 0) if used in parameter script, causing additional warning.

n = REQUEST ("Name_of_line_type", index, name)

Returns in the given variable the line name identified by index.
Expression returns 0 and contains dummy return values (emtpy string or 0) if used in parameter script, causing additional warning.

n = REQUEST ("Name_of_style", index, name)

Returns in the given variable the name of the style identified by index.
Expression returns 0 and contains dummy return values (emtpy string or 0) if used in parameter script, causing additional warning.

If index < 0, it refers to a material, fill, line type or style defined in the GDL script or the MASTER_GDL file.
A call of a request with index = 0 returns in the variable the name of the default material or line type. (Empty string for fill and style.)

The return value of the request is the number of successfully retrieved values
(1 if no error occurred, 0 for error when the index is not valid).

n = REQUEST ("WINDOW_DOOR_SHOW_DIM", "", show)

Before 9.0 returns 1 in the show variable if Options/Display Options/Doors & Windows is set to “Show with Dimensions”, 0 otherwise.
Since 9.0 display options were split to separate Door and Window display options,
so for compatibility reasons checks if the request is used in a Window (or marker of a Window) or a Door (or marker of a Door)
and automatically returns the corresponding display option. In other cases (symbol, lamp, label) the Window option is returned.
Can be used to hide/show custom dimensions according to the current Display Options.
Expression returns 0 and contains dummy return values (emtpy string or 0) if used in parameter script, causing additional warning.

Since 9.0 the “window_show_dim”, and the “door_show_dim” separate requests are available.

n = REQUEST ("window_show_dim", "", show)

Returns 1 in the show variable if in the Model View Options/Window options the “with Markers” is checked, 0 otherwise.
Expression returns 0 and contains dummy return values (emtpy string or 0) if used in parameter script, causing additional warning.

n = REQUEST ("door_show_dim", "", show)

Returns 1 in the show variable if in the Model View Options/Door options the “with Markers” is checked, 0 otherwise.
Expression returns 0 and contains dummy return values (emtpy string or 0) if used in parameter script, causing additional warning.

n = REQUEST ("name_of_listed", "", name)

Returns in the name variable the name of the library part associated with the property type library part containing this request.
For elements (Walls, Slabs, etc.), the name is an empty string.
Expression returns 0 and contains dummy return values (emtpy string or 0) if used in parameter script, causing additional warning.

n = REQUEST ("window_door_zone_relev", "", out_direction)

Effective only for Doors and Windows. Use it as complement to the “zone_relations” request.
Returns 1 in the out_direction variable if the Door/Window opening direction is in that of the first room identified by the “zone_relations” request,
2 if the opening direction is towards the second room. It also returns 2 if there is only one room and the opening direction is to the outside.
Causes warning if used in parameter script.

n = REQUEST ("window_door_zone_relev_of_owner", "", out_direction)

Effective only if the library part’s parent is a door or a window (markers, labels).
Use it as a complement to the “zone_relations_of_owner” request.
Returns 1 in the out_direction variable
if the parent’s opening direction is in that of the first zone identified by the zone relations type requests,
2 if the opening direction is towards the second zone. It also returns 2 if there is only one zone and the opening direction is to the outside.
Causes warning if used in parameter script.

n = REQUEST ("matching_properties", type, name1, name2, ..)

If type = 1, returns in the given variables individually associated property library part names, otherwise property library
part names associated by criteria. If used in an associative label,
the function returns the properties of the element the label is associated with.
Expression returns 0 and contains dummy return values (emtpy string or 0) if used in parameter script, causing additional warning.

n = REQUEST ("Working_length_unit", "", format_string) n = REQUEST ("Working_angle_unit", "", format_string)

With these requests, the user can get the working unit formats as set in the Options > Project Preferences > Working Units dialog box.
They return a format string that can be used as the first parameter in the STR () function.
The requests both work when interpreting the user interface script.
“Working_angle_unit” causes warning if used in parameter script.

n = REQUEST ("Model_length_unit", "", format_string)

n = REQUEST ("Layout_length_unit", "", format_string)

With these requests, the user can get the layout and the model unit formats as set in the Options > Project Preferences >
Working Units dialog box. They return a format string that can be used as the first parameter in the STR () function.
The requests work only when interpreting the user interface scripts, and cause warning if used in parameter script.

n = REQUEST ("Model_text_size_unit", "", format_string)

n = REQUEST ("Layout_text_size_unit", "", format_string)

With these requests, the user can get the layout and the model text size formats.
They return a format string that can be used as the first parameter in the STR () function.
The requests work only when interpreting the user interface scripts.
Both expressions returns 0 and contains dummy return values (emtpy string or 0) if used in parameter script, causing additional warning.

n = REQUEST ("Properties_Of_Parent", propertyType, parentProperties)

Compatibility: Introduced in ARCHICAD 20
Returns the properties of the parent object. All properties are returned in one array with the following form: ID, type, group, name. Can be used only in labels.
Expression returns 0 and contains dummy return values (emtpy string or 0) if used in parameter script, causing additional warning.

Core property:     [id,    "",               "",                   PropertyName]
AC property:       [guid,  "",               "GroupName",          PropertyName]
IFC property:      [id,    "IFC",            "GroupName",          PropertyName]
Classification:    [guid,  "Classification", "",                   PropertyName]
Profile parameter: [guid,  "",               "Profile Parameters", PropertyName]

Compatibility: the request is introduced in ARCHICAD 20. The property type options and the Classification property type are introduced in ARCHICAD 21, the Profile parameter property type is introduced in ARCHICAD 22.

Example 4:

DIM parentProperties[]
n = REQUEST ("Properties_Of_Parent", "", parentProperties)
! parentProperties =   [Id1, TypeName1, GroupName1, PropertyName1,
Id2, TypeName2, GroupName2, PropertyName2,
...
Idn, TypeNamen, GroupNamen, PropertyNamen]

n = REQUEST ("Property_Tree_Of_Parent", propTreeInput, propTreeOutput)

Compatibility: Introduced in ARCHICAD 25
Returns the tree of available properties of the parent object with a grouping similar to the property selector trees in Archicad. Can be used only in the UI Script of labels and markers. Expression returns 0 and contains dummy return values (emtpy dictionary) if used in other situations, causing additional warning.

DICT propTreeInput, propTreeOutput
n = REQUEST ("Property_Tree_Of_Parent", propTreeInput, propTreeOutput)
! propTreeOutput.treeDepth = m
! propTreeOutput.propertyTree =    [Id1, DisplayName11, ... DisplayName1m,
                                    Id2, DisplayName21, ... DisplayName2m,
                                    ...
                                    Idn, DisplayNamen1, ... DisplayNamenm]

DICT propTreeInput, propTreeOutput
n = REQUEST ("Property_Tree_Of_Parent", propTreeInput, propTreeOutput)
if n > 0 then 
    ui_custom_popup_infield "stParameterName", 10, 20, 300, 19,
        1, propTreeOutput.treeDepth, 1, "SelectedValueDescription",
        propTreeOutput.propertyTree									
endif

DIM propertyValues[]
n = REQUEST ("Property_Value_Of_Parent", "ExampleId", type, dim1, dim2, propertyValues)

dict propInputIds
	propInputIds.propertyIds[1].id = "ExampleId1"
	propInputIds.propertyIds[2].id = "ExampleId2"
	...
	propInputIds.propertyIds[n].id = "ExampleIdn"
dict propOutputVals
n = REQUEST ("Property_Values_Of_Parent", propInputIds, propOutputVals)
! propOutputVals
	.propertyValues[1].value_status
	.propertyValues[1].type
	.propertyValues[1].value[]
	.propertyValues[2].value_status
	.propertyValues[2].type
	.propertyValues[2].value[]
	...
	.propertyValues[n].value_status
	.propertyValues[n].type
	.propertyValues[n].value[]

AC property:       [guid,  "",               "GroupName",      PropertyName]
Classification:    [guid,  "Classification", "",               PropertyName]

DIM parentComponentProperties[]
n = REQUEST ("Component_Properties_Of_Parent", "", parentComponentProperties)
! parentComponentProperties =   [Id1, TypeName1, GroupName1, PropertyName1,
	                        Id2, TypeName2, GroupName2, PropertyName2,
	                       	...
	                        Idn, TypeNamen, GroupNamen, PropertyNamen]

DICT propTreeInput, propTreeOutput
n = REQUEST ("Component_Property_Tree_Of_Parent", propTreeInput, propTreeOutput)
! propTreeOutput.treeDepth = m
! propTreeOutput.propertyTree =    [Id1, DisplayName11, ... DisplayName1m,
                                    Id2, DisplayName21, ... DisplayName2m,
                                    ...
                                    Idn, DisplayNamen1, ... DisplayNamenm]

DICT propTreeInput, propTreeOutput
n = REQUEST ("Component_Property_Tree_Of_Parent", propTreeInput, propTreeOutput)
if n > 0 then 
    ui_custom_popup_infield "stParameterName", 10, 20, 300, 19,
        1, propTreeOutput.treeDepth, 1, "SelectedValueDescription",
        propTreeOutput.propertyTree									
endif

dict collectComponents
	collectComponents.collectMode = 1
dict outputCompIds
n = REQUEST ("Component_IDs_Of_Parent", collectComponents, outputCompIds)
! outputCompIds
	.componentIds[1].id
	.componentIds[2].id
	...
	.componentIds[n].id

dict compPropInput
	compPropInput.componentId.id = iActualID	! From "Component_IDs_Of_Parent" request
	compPropInput.propertyIds[1].id = "ExampleId1"
	compPropInput.propertyIds[2].id = "ExampleId2"
	...
	compPropInput.propertyIds[n].id = "ExampleIdn"
dict compPropVals
n = REQUEST ("Component_Property_Values_Of_Parent", compPropInput, compPropVals)
! compPropVals =  .propertyValues[1].value_status
		.propertyValues[1].type
		.propertyValues[1].value[]
		.propertyValues[2].value_status
		.propertyValues[2].type
		.propertyValues[2].value[]
		...
		.propertyValues[n].value_status
		.propertyValues[n].type
		.propertyValues[n].value[]

DIM autoTextListArray[]
n = REQUEST ("AUTOTEXT_LIST", "", autoTextListArray)
! autoTextListArray =   [ID1, CategoryName1, TextName1,
                         ID2, CategoryName2, TextName2,
                         ...
                         IDn, CategoryNamen, TextNamen]

If dim2 > 0, then dim1 > 0.

DIM DATA []
n = REQUEST ("ASSOCEL_PROPERTIES", "iscomp, code, name", nr, data)
IF nr = 0 THEN
    TEXT2 0, 0, "No properties"
ELSE
    j = 0
    FOR i = 1 TO nr
        IF i MOD 3 = 0 THEN
            TEXT2 0, -j, DATA [i] ! name
            j = j + 1
        ENDIF
    NEXT i
ENDIF

DIM strings[]
n = REQUEST ("ANCESTRY_INFO", 1, name, guid, strings)
IF n > 2 THEN
    ! data of replaced library part
    TEXT2 0, -1, "replacing: " + name + ' ' + guid
    ! parents
    l = -2
    FOR i = 1 TO n - 2 STEP 2
        TEXT2 0, l, strings [ i ]
        l = l - 1
    NEXT i
ENDIF

n = REQUEST{2} ("Material_info", "Brick-Face", "gs_mat_ambient", a)
n = REQUEST{2} ("Material_info", 1, "gs_mat_surface_rgb", r, g, b)
n = REQUEST{2} ("Material_info", "Brick-Face", "gs_mat_texture",
            file_name, w, h, mask, alpha)
n = REQUEST{2} ("Material_info", "My-Material", "my_extra_parameter", e)

n = REQUEST{2} ("Building_Material_info", "Brick", "gs_bmat_id", id)
n = REQUEST{2} ("Building_Material_info", "Brick", "gs_bmat_surface", index)
n = REQUEST{2} ("Building_Material_info", "Brick", "gs_bmat_physical_properties",
            thermalConductivity, density, heatCapacity, embodiedEnergy, embodiedCarbon)

DICT InputAttributes, MEPRouteAttributes
n = REQUEST ("MEP_ROUTE_ATTRIBUTES", InputAttributes, MEPRouteAttributes)

dim fontnames[]
n = REQUEST ("FONTNAMES_LIST", "", fontnames)
VALUES "f" fontnames, CUSTOM

n = REQUEST ("COMPONENT_PROJECTED_AREA", 0, a)
COMPONENT "Projected Area", a, "m2"

n = REQUEST ("COMPONENT_VOLUME", 0, v)
COMPONENT "Volume", v, "m3"

n = REQUEST ("Profile_components", name_or_index, nComponents,
        compType1, compType2, ..., compTypen)

_nComponents = 0
dim _componentTypes[]
n = REQUEST ("Profile_components", myProfileIdx, _nComponents, _componentTypes

n = REQUEST ("Profile_default_geometry", name_or_index, n1, n2, ..., nm,
            x11, y11, edgeVisible11, vertEdgeVisible11, additionalStatus11, ...,
            x1n1, y1n1, edgeVisible1n1, vertEdgeVisible1n1, additionalStatus1n1,
            x21, y21, edgeVisible21, vertEdgeVisible21, additionalStatus21, ...,
            x2n2, y2n2, edgeVisible2n2, vertEdgeVisible2n2, additionalStatus2n2, ...,
            xm1, ym1, edgeVisiblem1, vertEdgeVisiblem1, additionalStatusm1, ...,
            xmnm, ymnm, edgeVisiblemnm, vertEdgeVisiblemnm, additionalStatusmnm)

poly2Status = edgeVisible + additionalStatus
prismStatus = additionalStatus
tubeStatus = additionalStatus
if additionalStatus >= 0 then         ! not contour end
    if edgeVisible then
        prismStatus = prismStatus + 15    ! j1, j2, j3, j4
    endif
    if verticalEdgeVisible = 0 then
        prismStatus = prismStatus+ 64     ! j7
        ! in tube, lateral edges starting from the node are used for showing the contour
        tubeStatus = tubeStatus + 1
    endif
endif

n = REQUEST{4} ("Profile_component_info", name_or_index, component_ind, param_name,
            value1, value2, ..., valuen)